program oldstyle, textpatterns;

val sectionNumber = new Stack<Integer> ();
var inAppendix : boolean = false;
var copyright : String = "";
var bibliography : String = "";
val infoPart : TextPattern = anyText upto (/"::" | /"`");
var email : String = "";
var where : String = "TOP";

print ("<?xml version=\"1.0\" encoding=\"utf-8\"?>\n"
       "<!DOCTYPE article SYSTEM \"../balisage2019/balisage-1-3.dtd\">\n"
       "<article xmlns=\"http://docbook.org/ns/docbook\" "
       "xmlns:xlink=\"http://www.w3.org/1999/xlink\" "
       "version=\"5.0-subset Balisage-1.3\">\n");
with ruleSet = "main" do
  sendToMatch (System.in);
endSection (0);
print ("<bibliography><title>References</title>\n" +
       bibliography + "</bibliography>\n") when bibliography != "";
print ("</article>\n");

ruleSet "main":

match /".article" & [" \t"]+ & (anyText upto /"::") => "title" & /"::" &
      anyText* => "copyright" {
  print ("<title>" + => "title" + "</title>\n"
         "<info>\n");
  copyright = => "copyright";
}

match /".conf" & [" \t"]+ & (anyText upto /"::") => "name" & /"::" &
      anyText* => "date" {
  print ("<!-- <confgroup>\n"
         "<conftitle>%s</conftitle>\n"
	 "<confdates>%s</confdates>\n"
	 "</confgroup> -->\n" (=> "name", => "date"));
}

match /".abstract" {
  endInfoPart ("ABSTRACT");
  print ("<abstract>\n");
}

match /".author" & [" \t"]+ & \[":"]* => "first" & /":" &
      \[":"]* => "middle" & /":" & \[":"]* => "last" & /":" &
      anyText* => "email" {
  endInfoPart ("AUTHOR");
  email = => "email";
  print ("<author>\n"
         "<personname>");
  print ("<firstname>" + => "first" + "</firstname>")
    when => "first" != "";
  print ("<othername>" + => "middle" + "</othername>")
    when => "middle" != "";
  print ("<surname>" + => "last" + "</surname>")
    when => "last" != "";
  print ("</personname>\n"
         "<personblurb>\n");
  where = "AUTHOR";
}

match /".keyword" & [" \t"]+ {
  endInfoPart ("KEYWORD");
  print ("<keywordset role=\"author\">\n");
  selectAll * {
    match (anyText upto ",") => "keyword" & /"," & /" "* |
          anyText+ => "keyword":
      print ("<keyword>" + => "keyword" + "</keyword>\n");
  }
  print ("</keywordset>\n");
}

match /".appendix" & [" \t"] & 
      ((anyText upto "::") => "title" & /"::" & anyText* => "subtitle" |
       anyText* => "title" & /"" => "subtitle") {
  endInfoPart ("BODY");
  startSection (1, => "title", true, => "subtitle");
}

match /".h" & ["01234"] => "level" & [" \t"]+ &
      ((anyText upto "::") => "title" & /"::" & anyText* => "subtitle" |
       anyText* => "title" & /"" => "subtitle") {
  endInfoPart ("BODY");
  startSection (=> "level" into integer, => "title", false, => "subtitle");
}

match /".endFootnote" &? /"\n" {
  return;
}

match ? anyText {
  print ("<para>");
  processParagraph (*);
  select * {
    match /"\n"* &? /"=":
      print ("<itemizedlist>\n");
      selectAll currentInput {
        match /"\n"* & /"=" & [" \t"]*:
          print ("<listitem><para>");
	  processParagraph (*);
          print ("</para></listitem>\n");
      }
      print ("</itemizedlist>");
    match /"\n"* & /":" & /" "?:
      print ("<programlisting xml:space=\"preserve\">");
      selectAll currentInput {
	match \["<>&\n"]+ => "asis": print (=> "asis");
	match /"<": print ("&lt;");
	match /">": print ("&gt;");
	match /"&": print ("&amp;");
	match /"\n"+ & /":" & /" "?: print ("\n");
	match /"\n": break;
      }
      print ("</programlisting>");
  }
  print ("</para>\n");
}

def endInfoPart (newWhere : String) {
  select where {
    case "ABSTRACT":
      print ("</abstract>\n");
    case "AUTHOR":
      print ("</personblurb>\n");
      print ("<email>" + email + "</email>\n") when email != "";
      print ("</author>\n");
      print ("<!-- <legalnotice><para>Copyright &#169; " + copyright +
             "</para></legalnotice> -->\n")
        when copyright != "";
  }
  print ("</info>\n") when where != "BODY" and newWhere == "BODY";
  where = newWhere;
}

def processParagraph (source : String) {
  processParagraph (new MatchableInput (source));
}

def processParagraph (source : MatchableInput) {
  selectAll source {
    match /"``":
      print ("`");
    match /"`footnote`\n":
      print ("<footnote>");
      with ruleSet = "main" do
        sendToMatch (currentInput);
      print ("</footnote> ");
    match /"`BJ`":
      print ("<emphasis role=\"bital\">%s</emphasis>" (languageName));
    match /"`" & (/"bold" | /"ital" | /"bital" | /"rom" | /"under") => "role" &
          /":" & \["`"]* => "words" & /"`"?:
      print ("<emphasis role=\"%s\">%s</emphasis>" (=> "role", => "words"));
    match /"`" & infoPart => "key" & /"::"? & infoPart => "label" & /"::"? &
          infoPart => "title" & /"::"? & infoPart => "url" & /"`":
      var http : String =  (if => "url" matches (/"http" & /"s"? & /":" | -|)
	                    then "" else "http://") + => "url";
      print ("<xref linkend=\"" + => "key" + "\"/>");
      bibliography += "<bibliomixed xml:id=\"%s\" xreflabel=\"%s\">%s"
		      (=> "key", => "label",
		       if => "title" == "" then => "label" else => "title");
      bibliography += "<link xlink:href=\"%s\" xlink:type=\"simple\" "
                      "xlink:show=\"new\" xlink:actuate=\"onRequest\">%s"
		      "</link>" (http, http) when http != "";
      bibliography += "</bibliomixed>\n";
    match /"`" & ? anyText [0, 20] => "following":
      System.err.printf ("ERROR: unpaired ` prior to \"%s\"\n"
                         (=> "following"));
    match \["`<>&\n"]+ => "other":
      print (=> "other");
    match /"<":
      print ("&lt;");
    match /">":
      print ("&gt;");
    match /"&":
      print ("&amp;");
    match /"\n" &! [".=:\n"]:
      print ("\n");
    match /"\n":
      break;
  }
}

def endSection (level : integer) {
  while length sectionNumber > 0 and length sectionNumber >= level do {
    print ("<!-- end section level = %d, new level = %d, inAppendix = %s -->"
           (length sectionNumber, level, inAppendix));
    println (if inAppendix and length sectionNumber == 1 then "</appendix>"
                                                         else "</section>");
    sectionNumber.pop ();
  }
  if length sectionNumber > 0 then
    with thisSectionNumber : Integer = sectionNumber.pop () do
      sectionNumber.push (thisSectionNumber.intValue () + 1);
}

def startSection (level : integer, title : String, startsAppendix : boolean,
                  subtitle : String = "") {
  endSection (level);
  inAppendix or= startsAppendix;
  var sectionStart : String = if inAppendix and length sectionNumber == 0
                              then "<appendix>" else "<section>";
  print ("<!-- start section level = %d, new level = %d, inAppendix = %s -->"
         (length sectionNumber, level, inAppendix));
  while length sectionNumber < level - 1 do {
    sectionNumber.push (1);
    println ("%s<title>Section %s</title>\n" (sectionStart,
                                              getSectionNumber ()));
    sectionStart = "<section>";
  }
  print ("%s<title>" (sectionStart));
  processParagraph (title);
  print ("</title>");
  if subtitle != "" then {
    print ("<subtitle>");
    processParagraph (subtitle);
    print ("</subtitle>");
  }
  println ();
  sectionNumber.push (1);
}

def getSectionNumber () : String {
  val parts = new ArrayList<Integer> ();
  until sectionNumber.empty () do
    parts.add (0, sectionNumber.pop ());
  var result : String = "";
  for i = length parts - 1 by -1 to 1 do
    result += "%s." (parts [i]);
  result += "%s" (parts [0]);
  for p = parts do
    sectionNumber.push (p);
  return result;
}